feat(fontlock): fontify ${} expressions inside backticks

Author: Fuco1

typescript-mode-general-tests.el

@@ -846,6 +846,31 @@ bbb: Bar,
     (should (eq (get-face-at "aaa") 'font-lock-variable-name-face))
     (should (eq (get-face-at "bbb") 'font-lock-variable-name-face))))
 
+(ert-deftest font-lock/backticks--expr-fontification--with-variable ()
+  (test-with-fontified-buffer
+      "const x = `hello ${world}`"
+    (should (eq (get-face-at "${") 'font-lock-keyword-face))
+    (should (eq (get-face-at "world") 'default))
+    (should (eq (get-face-at "}") 'font-lock-keyword-face))))
+
+(ert-deftest font-lock/backticks--expr-fontification--not-in-regular-string ()
+  (test-with-fontified-buffer
+      "const x = 'hello ${world}'"
+    (should (eq (get-face-at "${") 'font-lock-string-face))
+    (should (eq (get-face-at "world") 'font-lock-string-face))
+    (should (eq (get-face-at "}") 'font-lock-string-face))))
+
+(ert-deftest font-lock/backticks--expr-fontification--with-funcall ()
+  "For now function calls or any other expressions are fontified as
+if a simple variable token in its entirety.  When/if this is
+implemented better, this test should be adjusted to capture the
+new functionality."
+  (test-with-fontified-buffer
+      "const x = `hello ${parseInt(foobar)}`"
+    (should (eq (get-face-at "${") 'font-lock-keyword-face))
+    (should (eq (get-face-at "parseInt(foobar)") 'default))
+    (should (eq (get-face-at "}") 'font-lock-keyword-face))))
+
 (defun flyspell-predicate-test (search-for)
   "This function runs a test on
 `typescript--flyspell-mode-predicate'.  `SEARCH-FOR' is a string

typescript-mode.el

@@ -2089,6 +2089,20 @@ This performs fontification according to `typescript--class-styles'."
         return t
         else do (goto-char orig-end)))
 
+(defun typescript--match-subst-in-quotes (limit)
+  "Match dollar substitutions inside backticks."
+  (catch 'done
+    (while (re-search-forward
+            ;; `rx' is cool, mkay.
+            (rx (or line-start (not (any "\\")))
+                (group "${")
+                (group (+? nonl))
+                (group "}"))
+            limit t)
+      (let ((string-delim (nth 3 (syntax-ppss))))
+        (when (and string-delim (= string-delim 96))
+          (throw 'done (point)))))))
+
 (defconst typescript--font-lock-keywords-4
   `(
     ;; highlights that override previous levels
@@ -2144,7 +2158,12 @@ This performs fontification according to `typescript--class-styles'."
 
     ;; arrow function
     ("\\(=>\\)"
-     (1 font-lock-keyword-face)))
+     (1 font-lock-keyword-face))
+
+    (typescript--match-subst-in-quotes
+     (1 'font-lock-keyword-face t)
+     (2 'default t)
+     (3 'font-lock-keyword-face t)))
   "Level four font lock for `typescript-mode'.")
 
 (defconst typescript--font-lock-keywords