-
Notifications
You must be signed in to change notification settings - Fork 14
/
Copy pathcfdcomplementonomina.prg
401 lines (336 loc) · 12.5 KB
/
cfdcomplementonomina.prg
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
* CFDComplementoNomina
* Implementa el complemento para nominas
*
* --
** Autores: Victor Espina / Arturo Ramos
**
** ARC Mar 17, 2014 - Se Agrega soporte para nodos Percepciones, Deducciones, Incapacidades y Horasextras
**
*
DEFINE CLASS CFDComplementoNomina AS ICFDAddenda
*
#DEFINE CFD_OPCIONAL .T.
nodeName = "Complemento" && Define el nombre del nodo (por defecto es Addenda)
NSTag = "nomina"
NSUrl = "http://www.sat.gob.mx/nomina"
schemaLocation = "http://www.sat.gob.mx/nomina http://www.sat.gob.mx/sitio_internet/cfd/nomina/nomina11.xsd"
version = "1.1" && Atributo requerido con valor prefijado a 1.0 que indica la versión del estándar bajo el que se encuentra expresado el complemento concepto al comprobante.
RegistroPatronal = ""
NumEmpleado = ""
CURP = ""
TipoRegimen = 0
NumSeguridadSocial = ""
FechaPago = ""
FechaInicialPago = ""
FechaFinalPago = ""
NumDiasPagados = ""
Departamento = ""
CLABE = ""
Banco = 0
FechaInicioRelLaboral = ""
Antiguedad = 0
Puesto = ""
TipoContrato = ""
TipoJornada = ""
PeriodicidadPago = ""
SalarioBaseCotApor = ""
RiesgoPuesto = 0
SalarioDiarioIntegrado = ""
lIncluirPercepciones = .F. && El nodo de Percepciones es opcional, si es .T. se inlcuye
Percepciones = NULL
lIncluirDeducciones = .F. && El nodo de Deducciones es opcional, si es .T. se inlcuye
Deducciones = NULL
lIncluirIncapacidades = .F. && El nodo de Incapacidades es opcional, si es .T. se inlcuye
Incapacidades = NULL
lIncluirHorasExtras = .F. && El nodo de HorasExtras es opcional, si es .T. se inlcuye
HorasExtras = NULL
PROCEDURE Init
DODEFAULT()
THIS.Percepciones = CREATEOBJECT("CFDComplementoNominaPercepciones")
THIS.Deducciones = CREATEOBJECT("CFDComplementoNominaDeducciones")
THIS.Incapacidades = CREATEOBJECT("CFDComplementoNominaIncapacidades")
THIS.HorasExtras = CREATEOBJECT("CFDComplementoNominaHorasExtras")
ENDPROC
PROCEDURE ToString()
*
LOCAL oParser,oRoot
oParser = CREATE("XMLParser")
oParser.indentString = ""
oParser.New()
oRoot = oParser.XML.addNode("nomina:Nomina")
oRoot.createNodeLinks = .F.
oRoot.addProp("Version", THIS.Version)
oRoot.addProp("RegistroPatronal", THIS._fixStr(THIS.RegistroPatronal), CFD_OPCIONAL)
oRoot.addProp("NumEmpleado", THIS._fixStr(THIS.NumEmpleado))
oRoot.addProp("CURP", THIS._fixStr(THIS.CURP))
oRoot.addProp("TipoRegimen", IIF(THIS.TipoRegimen > 0, ALLTRIM(STR(THIS.TipoRegimen,15,0)), ""))
oRoot.addProp("NumSeguridadSocial", THIS._fixStr(THIS.NumSeguridadSocial), CFD_OPCIONAL)
oRoot.addProp("FechaPago", THIS._fixStr(THIS.FechaPago))
oRoot.addProp("FechaInicialPago", THIS._fixStr(THIS.FechaInicialPago))
oRoot.addProp("FechaFinalPago", THIS._fixStr(THIS.FechaFinalPago))
oRoot.addProp("NumDiasPagados", THIS._fixStr(THIS.NumDiasPagados))
oRoot.addProp("Departamento", THIS._fixStr(THIS.Departamento), CFD_OPCIONAL)
oRoot.addProp("CLABE", THIS._fixStr(THIS.CLABE), CFD_OPCIONAL)
oRoot.addProp("Banco", IIF(THIS.Banco > 0, PADL(THIS.Banco,3,"0"), ""),CFD_OPCIONAL)
oRoot.addProp("FechaInicioRelLaboral", THIS._fixStr(THIS.FechaInicioRelLaboral), CFD_OPCIONAL)
oRoot.addProp("Antiguedad", IIF(THIS.Antiguedad > 0, ALLTRIM(STR(THIS.Antiguedad,15,0)), ""), CFD_OPCIONAL)
oRoot.addProp("Puesto", THIS._fixStr(THIS.Puesto), CFD_OPCIONAL)
oRoot.addProp("TipoContrato", THIS._fixStr(THIS.TipoContrato), CFD_OPCIONAL)
oRoot.addProp("TipoJornada", THIS._fixStr(THIS.TipoJornada), CFD_OPCIONAL)
oRoot.addProp("PeriodicidadPago", THIS._fixStr(THIS.PeriodicidadPago))
oRoot.addProp("SalarioBaseCotApor", THIS._fixStr(THIS.SalarioBaseCotApor), CFD_OPCIONAL)
oRoot.addProp("RiesgoPuesto", IIF(THIS.RiesgoPuesto > 0, STR(THIS.RiesgoPuesto,1,0), ""), CFD_OPCIONAL)
oRoot.addProp("SalarioDiarioIntegrado", THIS._fixStr(THIS.SalarioDiarioIntegrado), CFD_OPCIONAL)
* - PERCEPCIONES
IF THIS.lIncluirPercepciones THEN
THIS.Percepciones.ToXml(oRoot)
ENDIF
* - DEDUCCIONES
IF THIS.lIncluirDeducciones THEN
THIS.Deducciones.ToXml(oRoot)
ENDIF
* - INCAPACIDADES
IF THIS.lIncluirIncapacidades THEN
THIS.Incapacidades.ToXml(oRoot)
ENDIF
* - HORASEXTRAS
IF THIS.lIncluirHorasExtras THEN
THIS.HorasExtras.ToXml(oRoot)
ENDIF
RETURN oRoot.ToString()
*
ENDPROC
*-- _fixStr (Metodo)
* Recibe una cadena y realiza los siguientes cambios:
* a) Sustituye cualquier caracter invalido por el caracter "."
* b) Elimina los espacios en blanco al inicio y al final de la cadena
* c) Elimina cualquier secuencia de espacios en blanco repetidos dentro de la cadena
* d) Si la cadena resultante contiene al menos 1 caracter, se le anade la cadena
* indicada en el parametro pcSep
HIDDEN PROCEDURE _fixStr(puValue, pcSep)
*
IF PCOUNT() = 1
pcSep = ""
ENDIF
LOCAL cType
cType = VARTYPE(puValue)
DO CASE
CASE cType = "N"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN ALLT(STR(puValue,15,2)) + pcSep
CASE cType = "D"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN STR(YEAR(puValue),4) + "-" + PADL(MONTH(puValue),2,"0") + "-" + PADL(DAY(puValue),2,"0") + pcSEP
CASE cType = "T"
IF EMPTY(puValue)
RETURN ""
ENDIF
RETURN STR(YEAR(puValue),4) + "-" + PADL(MONTH(puValue),2,"0") + "-" + PADL(DAY(puValue),2,"0") + "T" + ;
PADL(HOUR(puValue),2,"0") + ":" + PADL(MINUTE(puValue),2,"0") + ":" + PADL(SEC(puValue),2,"0") + pcSEP
CASE cType = "X" && Valor NULL
RETURN ""
ENDCASE
LOCAL cFixed
cFixed = ALLTRIM(puValue)
cFixed = STRT(STRT(STRT(STRT(STRT(cFixed,[&],[&]),[<],[<]),[>],[>]),["],["]),['],['])
cFixed = STRT(cFixed, CHR(13)+CHR(10), "")
DO WHILE AT(SPACE(2), cFixed) <> 0
cFixed = STRTRAN(cFixed,SPACE(2),SPACE(1))
ENDDO
IF LEN(cFixed) > 0 AND !EMPTY(pcSep)
cFixed = cFixed + pcSep
ENDIF
RETURN cFixed
*
ENDPROC
PROCEDURE Version_Assign(vNewVal)
ENDPROC
*
ENDDEFINE
* P E R C E P C I O N E S
* CFDComplementoNominaPercepciones
* Representa los datos del nodo "nomina:Percepciones"
*
DEFINE CLASS CFDComplementoNominaPercepciones AS CFDCollection
TotalGravado = 0.00
TotalExento = 0.00
PROCEDURE Add(pcTipoPercepcion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
LOCAL oPercepcion
oPercepcion = CREATEOBJECT("CFDComplementoNominaPercepcion", pcTipoPercepcion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
THIS.TotalGravado = THIS.TotalGravado + pnImporteGravado
THIS.TotalExento = THIS.TotalExento + pnImporteExento
RETURN DODEFAULT(oPercepcion)
ENDPROC
PROCEDURE ToXML(poParentNode)
LOCAL oNodo,i,oPercepcion
oNodo = poParentNode.addNode("nomina:Percepciones")
oNodo.addProp("TotalGravado",ALLTRIM(STR(THIS.TotalGravado,15,2)))
oNodo.addProp("TotalExento",ALLTRIM(STR(THIS.TotalExento,15,2)))
oNodo.createNodeLinks = .F.
FOR i = 1 TO THIS.Count
oPercepcion = THIS.Items[i]
oPercepcion.ToXml(oNodo)
ENDFOR
ENDPROC
ENDDEFINE
* CFDComplementoNominaPercepcion
* Representa los datos del nodo "nomina:Percepcion"
DEFINE CLASS CFDComplementoNominaPercepcion AS Custom
TipoPercepcion = ""
Clave = ""
Concepto = ""
ImporteGravado = 0.00
ImporteExento = 0.00
PROCEDURE Init(pcTipoPercepcion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
THIS.TipoPercepcion = pcTipoPercepcion
THIS.Clave = pcClave
THIS.Concepto = pcConcepto
THIS.ImporteGravado = pnImporteGravado
THIS.ImporteExento = pnImporteExento
ENDPROC
PROCEDURE ToXml(poParentNode)
LOCAL oNodo
oNodo = poParentNode.addNode("nomina:Percepcion")
oNodo.addProp("TipoPercepcion",THIS.TipoPercepcion)
oNodo.addProp("Clave", THIS.Clave)
oNodo.addProp("Concepto", THIS.Concepto)
oNodo.addProp("ImporteGravado",ALLTRIM(STR(THIS.ImporteGravado,15,2)))
oNodo.addProp("ImporteExento",ALLTRIM(STR(THIS.ImporteExento,15,2)))
ENDPROC
ENDDEFINE
* D E D U C C I O N E S
* CFDComplementoNominaDeducciones
* Representa los datos del nodo "nomina:Deducciones"
*
DEFINE CLASS CFDComplementoNominaDeducciones AS CFDCollection
TotalGravado = 0.00
TotalExento = 0.00
PROCEDURE Add(pcTipoDeduccion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
LOCAL oDeduccion
oDeduccion = CREATEOBJECT("CFDComplementoNominaDeduccion", pcTipoDeduccion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
THIS.TotalGravado = THIS.TotalGravado + pnImporteGravado
THIS.TotalExento = THIS.TotalExento + pnImporteExento
RETURN DODEFAULT(oDeduccion)
ENDPROC
PROCEDURE ToXML(poParentNode)
LOCAL oNodo,i,oDeduccion
oNodo = poParentNode.addNode("nomina:Deducciones")
oNodo.addProp("TotalGravado",ALLTRIM(STR(THIS.TotalGravado,15,2)))
oNodo.addProp("TotalExento",ALLTRIM(STR(THIS.TotalExento,15,2)))
oNodo.createNodeLinks = .F.
FOR i = 1 TO THIS.Count
oDeduccion = THIS.Items[i]
oDeduccion.ToXml(oNodo)
ENDFOR
ENDPROC
ENDDEFINE
* CFDComplementoNominaDeduccion
* Representa los datos del nodo "nomina:Deduccion"
DEFINE CLASS CFDComplementoNominaDeduccion AS Custom
TipoDeduccion = ""
Clave = ""
Concepto = ""
ImporteGravado = 0.00
ImporteExento = 0.00
PROCEDURE Init(pcTipoDeduccion, pcClave, pcConcepto, pnImporteGravado, pnImporteExento)
THIS.TipoDeduccion = pcTipoDeduccion
THIS.Clave = pcClave
THIS.Concepto = pcConcepto
THIS.ImporteGravado = pnImporteGravado
THIS.ImporteExento = pnImporteExento
ENDPROC
PROCEDURE ToXml(poParentNode)
LOCAL oNodo
oNodo = poParentNode.addNode("nomina:Deduccion")
oNodo.addProp("TipoDeduccion",THIS.tipoDeduccion)
oNodo.addProp("Clave", THIS.Clave)
oNodo.addProp("Concepto", THIS.Concepto)
oNodo.addProp("ImporteGravado",ALLTRIM(STR(THIS.ImporteGravado,15,2)))
oNodo.addProp("ImporteExento",ALLTRIM(STR(THIS.ImporteExento,15,2)))
ENDPROC
ENDDEFINE
* I N C A P A C I D A D E S
* CFDComplementoNominaIncapacidades
* Representa los datos del nodo "nomina:Incapacidades"
*
DEFINE CLASS CFDComplementoNominaIncapacidades AS CFDCollection
PROCEDURE Add(pnDiasIncapacidad, pnTipoIncapacidad, pnDescuento)
LOCAL oIncapacidad
oIncapacidad = CREATEOBJECT("CFDComplementoNominaIncapacidad", pnDiasIncapacidad, pnTipoIncapacidad, pnDescuento)
RETURN DODEFAULT(oIncapacidad)
ENDPROC
PROCEDURE ToXML(poParentNode)
LOCAL oNodo,i,oIncapacidad
oNodo = poParentNode.addNode("nomina:Incapacidades")
oNodo.createNodeLinks = .F.
FOR i = 1 TO THIS.Count
oIncapacidad = THIS.Items[i]
oIncapacidad.ToXml(oNodo)
ENDFOR
ENDPROC
ENDDEFINE
* CFDComplementoNominaIncapacidad
* Representa los datos del nodo "nomina:Incapacidad"
DEFINE CLASS CFDComplementoNominaIncapacidad AS Custom
DiasIncapacidad = 0.00
TipoIncapacidad = 0
Descuento = 0.00
PROCEDURE Init(pnDiasIncapacidad, pnTipoIncapacidad, pnDescuento)
THIS.DiasIncapacidad = pnDiasIncapacidad
THIS.TipoIncapacidad = pnTipoIncapacidad
THIS.Descuento = pnDescuento
ENDPROC
PROCEDURE ToXml(poParentNode)
LOCAL oNodo
oNodo = poParentNode.addNode("nomina:Incapacidad")
oNodo.addProp("DiasIncapacidad", ALLTRIM(STR(THIS.DiasIncapacidad,15,2)))
oNodo.addProp("TipoIncapacidad", ALLTRIM(STR(THIS.TipoIncapacidad)))
oNodo.addProp("Descuento", ALLTRIM(STR(THIS.Descuento,15,2)))
ENDPROC
ENDDEFINE
* H O R A S E X T R A S
* CFDComplementoNominaHorasExtras
* Representa los datos del nodo "nomina:HorasExtras"
*
DEFINE CLASS CFDComplementoNominaHorasExtras AS CFDCollection
PROCEDURE Add(pnImportePagado, pnHorasExtra, pcTipoHoras, pnDias)
LOCAL oHorasExtra
oHorasExtra = CREATEOBJECT("CFDComplementoNominaHorasExtra", pnImportePagado, pnHorasExtra, pcTipoHoras, pnDias)
RETURN DODEFAULT(oHorasExtra)
ENDPROC
PROCEDURE ToXML(poParentNode)
LOCAL oNodo,i,oHorasExtra
oNodo = poParentNode.addNode("nomina:HorasExtras")
oNodo.createNodeLinks = .F.
FOR i = 1 TO THIS.Count
oHorasExtra = THIS.Items[i]
oHorasExtra.ToXml(oNodo)
ENDFOR
ENDPROC
ENDDEFINE
* CFDComplementoNominaHorasExtra
* Representa los datos del nodo "nomina:HorasExtra"
DEFINE CLASS CFDComplementoNominaHorasExtra AS Custom
Dias = 0
TipoHoras = ""
HorasExtra = 0
ImportePagado = 0.0
PROCEDURE Init(pnDias, pcTipoHoras, pnHorasExtra, pnImportePagado)
THIS.Dias = pnDias
THIS.TipoHoras = pcTipoHoras
THIS.HorasExtra = pnHorasExtra
THIS.ImportePagado = pnImportePagado
ENDPROC
PROCEDURE ToXml(poParentNode)
LOCAL oNodo
oNodo = poParentNode.addNode("nomina:HorasExtra")
oNodo.addProp("Dias", ALLTRIM(STR(THIS.Dias)))
oNodo.addProp("TipoHoras", THIS.TipoHoras)
oNodo.addProp("HorasExtra", ALLTRIM(STR(THIS.HorasExtra)))
oNodo.addProp("ImportePagado", ALLTRIM(STR(THIS.ImportePagado,15,2)))
ENDPROC
ENDDEFINE