opal/mca/if: fix "struct sockaddr_in" and OS checks

jsquyres · jsquyres · commit 7e80e2ffe69e · 2025-04-25T14:22:28.000-04:00
Found a few more places we needed to adjust for changing from
OPAL_CHECK_OS_FLAVORS to OAC_CHECK_OS_FLAVORS.

Also, in the opal/mca/if components, we have configure.m4 scripts that
explicitly check $opal_found_sockaddr.  This was a problem for a few
reasons:

1. We just deleted the setting of $opal_found_sockaddr from the
   previous OPAL_CHECK_OS_FLAVORS macro (*why* it was set in that
   macro isn't really clear -- "struct sockaddr" doesn't really have
   anything to do with checking OS flavors).
2. The old OPAL_CHECK_OS_FLAVORS macro actually checking for "struct
   sockaddr_in", not "struct sockaddr".  This led to a lot of
   confusion in this round of debugging.

Also, the additional network header checks and check for struct
sockaddr_in in OPAL_CHECK_OS_FLAVORS were redundant: they were already
being performed in OMPI's top-level configure.ac.  Deleting these
redundant tests -- and indeed, deleting all of OPAL_CHECK_OS_FLAVORS
-- is fine.  But we did need to set a global variable for the
opal/mca/if/*/configure.m4 scripts to check.  This commit therefore
adjusts the top-level configure.ac script to explicitly save the
result of checking for "struct sockaddr_in" into
$opal_found_sockaddr_in.

Finally, slightly change the AC_MSG_RESULT output in the
opal/mca/if/*/configure.m4 scripts to make it clear that the check for
"struct sockaddr_in" is *not* using the regular AC_CHECK_TYPES method.
Instead, the "cached" results it is getting are from OPAL caching, not
regular Autoconf test caching.  Do this because the "(cached)" output
that it previously emitted caused considerable confusion during this
round of debugging (i.e., I assumed it was coming from regular
Autoconf test caching, which is an entirely different mechanism).

Signed-off-by: Jeff Squyres &lt;jeff@squyres.com&gt;
diff --git a/configure.ac b/configure.ac
@@ -28,7 +28,7 @@
 # Copyright (c) 2018      FUJITSU LIMITED.  All rights reserved.
 # Copyright (c) 2019      Triad National Security, LLC. All rights
 #                         reserved.
-# Copyright (c) 2023      Jeffrey M. Squyres.  All rights reserved.
+# Copyright (c) 2023-2025 Jeffrey M. Squyres.  All rights reserved.
 # Copyright (c) 2025      Nanook Consulting  All rights reserved.
 # $COPYRIGHT$
 #
@@ -735,7 +735,26 @@ AC_CACHE_SAVE
 
 opal_show_title "Type tests"
 
-AC_CHECK_TYPES([socklen_t, struct sockaddr_in, struct sockaddr_in6,
+# We check elsewhere in configure tests if sockaddr_in is supported,
+# so explicitly save the result of that test.
+AC_CHECK_TYPES([struct sockaddr_in],
+               [opal_found_sockaddr_in=yes],
+               [opal_found_sockaddr_in=no],
+               [AC_INCLUDES_DEFAULT
+#if HAVE_SYS_SOCKET_H
+#include <sys/socket.h>
+#endif
+#ifdef HAVE_NETINET_IN_H
+#include <netinet/in.h>
+#endif
+#ifdef HAVE_LINUX_ETHTOOL_H
+#include <linux/ethtool.h>
+#endif
+#ifdef HAVE_NET_IF_H
+#include <net/if.h>
+#endif])
+
+AC_CHECK_TYPES([socklen_t, struct sockaddr_in6,
                 struct sockaddr_storage, struct ifreq, struct ethtool_cmd],
                [], [], [AC_INCLUDES_DEFAULT
 #if HAVE_SYS_SOCKET_H
diff --git a/opal/mca/if/bsdx_ipv4/configure.m4 b/opal/mca/if/bsdx_ipv4/configure.m4
@@ -4,6 +4,7 @@
 # Copyright (c) 2015      Research Organization for Information Science
 #                         and Technology (RIST). All rights reserved.
 # Copyright (c) 2025      Nanook Consulting  All rights reserved.
+# Copyright (c) 2025      Jeffrey M. Squyres.  All rights reserved.
 # $COPYRIGHT$
 #
 # Additional copyrights may follow
@@ -29,19 +30,18 @@ AC_DEFUN([MCA_opal_if_bsdx_ipv4_CONFIG], [
     # happy.  I.e., this:
     #if defined(__NetBSD__) || defined(__FreeBSD__) || \
     #    defined(__OpenBSD__) || defined(__DragonFly__)
-    AC_MSG_CHECKING([struct sockaddr])
-    AS_IF([test "$opal_found_sockaddr" = "yes"],
-          [AC_MSG_RESULT([yes (cached)])
+    AC_MSG_CHECKING([struct sockaddr_in])
+    AS_IF([test "$opal_found_sockaddr_in" = "yes"],
+          [AC_MSG_RESULT([yes (OPAL cached)])
            AC_MSG_CHECKING([NetBSD, FreeBSD, OpenBSD, or DragonFly])
-           AS_IF([test "$opal_found_netbsd" = "yes" || \
-                  test "$opal_found_freebsd" = "yes" || \
-                  test "$opal_found_openbsd" = "yes" || \
-                  test "$opal_found_dragonfly" = "yes"],
+           AS_IF([test "$oac_found_netbsd" = "yes" || \
+                  test "$oac_found_freebsd" = "yes" || \
+                  test "$oac_found_openbsd" = "yes" || \
+                  test "$oac_found_dragonfly" = "yes"],
                  [AC_MSG_RESULT([yes])
                   $1],
                  [AC_MSG_RESULT([no])
                   $2])],
-          [AC_MSG_RESULT([no (cached)])
+          [AC_MSG_RESULT([no (OPAL cached)])
            $2])
 ])
-
diff --git a/opal/mca/if/bsdx_ipv6/configure.m4 b/opal/mca/if/bsdx_ipv6/configure.m4
@@ -4,6 +4,7 @@
 # Copyright (c) 2015      Research Organization for Information Science
 #                         and Technology (RIST). All rights reserved.
 # Copyright (c) 2025      Nanook Consulting  All rights reserved.
+# Copyright (c) 2025      Jeffrey M. Squyres.  All rights reserved.
 # $COPYRIGHT$
 #
 # Additional copyrights may follow
@@ -29,20 +30,20 @@ AC_DEFUN([MCA_opal_if_bsdx_ipv6_CONFIG], [
     # happy.  I.e., this:
     #if defined( __NetBSD__) || defined(__OpenBSD__) || defined(__FreeBSD__) || \
     #             defined(__386BSD__) || defined(__bsdi__) || defined(__APPLE__)
-    AC_MSG_CHECKING([struct sockaddr])
-    AS_IF([test "$opal_found_sockaddr" = "yes"],
-          [AC_MSG_RESULT([yes (cached)])
+    AC_MSG_CHECKING([struct sockaddr_in])
+    AS_IF([test "$opal_found_sockaddr_in" = "yes"],
+          [AC_MSG_RESULT([yes (OPAL cached)])
            AC_MSG_CHECKING([some flavor of BSD])
-           AS_IF([test "$opal_found_netbsd" = "yes" || \
-                  test "$opal_found_freebsd" = "yes" || \
-                  test "$opal_found_openbsd" = "yes" || \
-                  test "$opal_found_386bsd" = "yes" || \
-                  test "$opal_found_bsdi" = "yes" ||
-                  test "$opal_found_apple" = "yes"],
+           AS_IF([test "$oac_found_netbsd" = "yes" || \
+                  test "$oac_found_freebsd" = "yes" || \
+                  test "$oac_found_openbsd" = "yes" || \
+                  test "$oac_found_386bsd" = "yes" || \
+                  test "$oac_found_bsdi" = "yes" ||
+                  test "$oac_found_apple" = "yes"],
                  [AC_MSG_RESULT([yes])
                   $1],
                  [AC_MSG_RESULT([no])
                   $2])],
-          [AC_MSG_RESULT([no (cached)])
+          [AC_MSG_RESULT([no (OPAL cached)])
            $2])
 ])dnl
diff --git a/opal/mca/if/linux_ipv6/configure.m4 b/opal/mca/if/linux_ipv6/configure.m4
@@ -4,6 +4,7 @@
 # Copyright (c) 2015      Research Organization for Information Science
 #                         and Technology (RIST). All rights reserved.
 # Copyright (c) 2025      Nanook Consulting  All rights reserved.
+# Copyright (c) 2025      Jeffrey M. Squyres.  All rights reserved.
 # $COPYRIGHT$
 #
 # Additional copyrights may follow
@@ -28,7 +29,7 @@ AC_DEFUN([MCA_opal_if_linux_ipv6_CONFIG], [
     AC_MSG_CHECKING([if we are on Linux with TCP])
     # If we have struct sockaddr and we're on Linux, then we're
     # happy.
-    AS_IF([test "$opal_found_sockaddr" = "yes" && test "$opal_found_linux" = "yes"],
+    AS_IF([test "$opal_found_sockaddr_in" = "yes" && test "$oac_found_linux" = "yes"],
           [AC_MSG_RESULT([yes])
            $1],
           [AC_MSG_RESULT([no])
diff --git a/opal/mca/if/posix_ipv4/configure.m4 b/opal/mca/if/posix_ipv4/configure.m4
@@ -4,6 +4,7 @@
 # Copyright (c) 2015      Research Organization for Information Science
 #                         and Technology (RIST). All rights reserved.
 # Copyright (c) 2025      Nanook Consulting  All rights reserved.
+# Copyright (c) 2025      Jeffrey M. Squyres.  All rights reserved.
 # $COPYRIGHT$
 #
 # Additional copyrights may follow
@@ -32,16 +33,16 @@ AC_DEFUN([MCA_opal_if_posix_ipv4_CONFIG], [
     # we're happy.  I.e., if posix but not:
     #if defined(__NetBSD__) || defined(__FreeBSD__) || \
     #    defined(__OpenBSD__) || defined(__DragonFly__)
-    AC_MSG_CHECKING([struct sockaddr])
-    AS_IF([test "$opal_found_sockaddr" = "yes"],
-          [AC_MSG_RESULT([yes (cached)])
+    AC_MSG_CHECKING([struct sockaddr_in])
+    AS_IF([test "$opal_found_sockaddr_in" = "yes"],
+          [AC_MSG_RESULT([yes (OPAL cached)])
            AC_MSG_CHECKING([not NetBSD, FreeBSD, OpenBSD, or DragonFly])
-           AS_IF([test "$opal_found_netbsd" = "no" && test "$opal_found_freebsd" = "no" && test "$opal_found_openbsd" = "no" && test "$opal_found_dragonfly" = "no"],
+           AS_IF([test "$oac_found_netbsd" = "no" && test "$oac_found_freebsd" = "no" && test "$oac_found_openbsd" = "no" && test "$oac_found_dragonfly" = "no"],
                  [AC_MSG_RESULT([yes])
                   opal_if_posix_ipv4_happy=yes],
                  [AC_MSG_RESULT([no])]
                 )],
-          [AC_MSG_RESULT([no (cached)])]
+          [AC_MSG_RESULT([no (OPAL cached)])]
          )
 
     AS_IF([test "$opal_if_posix_ipv4_happy" = "yes"],
