|
| 1 | +##---------------------------------------------------------------------------## |
| 2 | +## File : flibcpp/cmake/FlibcppVersion.cmake |
| 3 | +#[=======================================================================[.rst: |
| 4 | +
|
| 5 | +FlibcppVersion |
| 6 | +-------------- |
| 7 | +
|
| 8 | +.. command:: flibcpp_find_version |
| 9 | +
|
| 10 | + Get the project version using Git descriptions to ensure the version numbers |
| 11 | + are always synchronized between Git and CMake:: |
| 12 | +
|
| 13 | + flibcpp_find_version(<projname> <git-version-file>) |
| 14 | +
|
| 15 | +
|
| 16 | + ``<projname>`` |
| 17 | + Name of the project. |
| 18 | +
|
| 19 | + This command sets the following variables in the parent package:: |
| 20 | +
|
| 21 | + ${PROJNAME}_VERSION |
| 22 | + ${PROJNAME}_VERSION_STRING |
| 23 | +
|
| 24 | + The project version string uses PEP-440 semantic versioning, and will look |
| 25 | + like v0.1.2 if the version is actually a tagged release, or v0.1.3+abcdef if |
| 26 | + it's not. |
| 27 | +
|
| 28 | + If a non-tagged version is exported, or an untagged shallow git clone is used, |
| 29 | + it's impossible to determine the version from the tag, so a warning will be |
| 30 | + issued and the version will be set to 0.0.0. |
| 31 | +
|
| 32 | +#]=======================================================================] |
| 33 | + |
| 34 | +if (CMAKE_SCRIPT_MODE_FILE) |
| 35 | + cmake_minimum_required(VERSION 3.8) |
| 36 | +endif() |
| 37 | + |
| 38 | +function(flibcpp_find_version PROJNAME GIT_VERSION_FILE) |
| 39 | + # Get a possible Git version generated using git-archive (see the |
| 40 | + # .gitattributes file) |
| 41 | + file(STRINGS "${GIT_VERSION_FILE}" _TEXTFILE) |
| 42 | + |
| 43 | + if (_TEXTFILE MATCHES "\\$Format:") |
| 44 | + # Not a "git archive": use live git information |
| 45 | + set(_CACHE_VAR "${PROJNAME}_GIT_DESCRIBE") |
| 46 | + set(_CACHED_VERSION "${${_CACHE_VAR}}") |
| 47 | + if (NOT _CACHED_VERSION) |
| 48 | + # Building from a git checkout rather than a distribution |
| 49 | + find_package(Git QUIET REQUIRED) |
| 50 | + execute_process( |
| 51 | + COMMAND "${GIT_EXECUTABLE}" "describe" "--tags" "--match" "v*" |
| 52 | + WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}" |
| 53 | + ERROR_VARIABLE _GIT_ERR |
| 54 | + OUTPUT_VARIABLE _VERSION_STRING |
| 55 | + RESULT_VARIABLE _GIT_RESULT |
| 56 | + OUTPUT_STRIP_TRAILING_WHITESPACE |
| 57 | + ) |
| 58 | + if (NOT _GIT_RESULT EQUAL "0") |
| 59 | + message(WARNING "Failed to get ${PROJNAME} version from git: " |
| 60 | + "${_GIT_ERR}") |
| 61 | + elseif (NOT _VERSION_STRING) |
| 62 | + message(WARNING "Failed to get ${PROJNAME} version from git: " |
| 63 | + "git describe returned an empty string") |
| 64 | + else() |
| 65 | + # Process description tag: e.g. v0.4.0-2-gc4af497 or v0.4.0 |
| 66 | + string(REGEX MATCH "v([0-9.]+)(-[0-9]+-g([0-9a-f]+))?" _MATCH |
| 67 | + "${_VERSION_STRING}" |
| 68 | + ) |
| 69 | + if (_MATCH) |
| 70 | + set(_VERSION_STRING "${CMAKE_MATCH_1}") |
| 71 | + if (CMAKE_MATCH_2) |
| 72 | + # *not* a tagged release |
| 73 | + set(_VERSION_HASH "${CMAKE_MATCH_3}") |
| 74 | + endif() |
| 75 | + endif() |
| 76 | + endif() |
| 77 | + if (NOT _VERSION_STRING) |
| 78 | + execute_process( |
| 79 | + COMMAND "${GIT_EXECUTABLE}" "log" "-1" "--format=%h" "HEAD" |
| 80 | + WORKING_DIRECTORY "${CMAKE_CURRENT_LIST_DIR}" |
| 81 | + OUTPUT_VARIABLE _VERSION_HASH |
| 82 | + OUTPUT_STRIP_TRAILING_WHITESPACE |
| 83 | + ) |
| 84 | + endif() |
| 85 | + set(_CACHED_VERSION "${_VERSION_STRING}" "${_VERSION_HASH}") |
| 86 | + set("${_CACHE_VAR}" "${_CACHED_VERSION}" CACHE INTERNAL |
| 87 | + "Version string and hash for ${PROJNAME}") |
| 88 | + endif() |
| 89 | + list(GET _CACHED_VERSION 0 _VERSION_STRING) |
| 90 | + list(GET _CACHED_VERSION 1 _VERSION_HASH) |
| 91 | + else() |
| 92 | + # First line are decorators, second is hash. |
| 93 | + list(GET _TEXTFILE 0 _TAG) |
| 94 | + string(REGEX MATCH "tag: *v([0-9.]+)" _MATCH "${_TAG}") |
| 95 | + if (_MATCH) |
| 96 | + set(_VERSION_STRING "${CMAKE_MATCH_1}") |
| 97 | + else() |
| 98 | + # *not* a tagged release |
| 99 | + list(GET _TEXTFILE 1 _HASH) |
| 100 | + string(REGEX MATCH " *([0-9a-f]+)" _MATCH "${_HASH}") |
| 101 | + if (_MATCH) |
| 102 | + set(_VERSION_HASH "${CMAKE_MATCH_1}") |
| 103 | + endif() |
| 104 | + endif() |
| 105 | + endif() |
| 106 | + |
| 107 | + if (NOT _VERSION_STRING) |
| 108 | + message(WARNING "Could not determine version number for ${PROJNAME}: " |
| 109 | + "perhaps a non-release archive?") |
| 110 | + set(_VERSION_STRING "0.0.0") |
| 111 | + endif() |
| 112 | + |
| 113 | + if (_VERSION_HASH) |
| 114 | + set(_FULL_VERSION_STRING "v${_VERSION_STRING}+${_VERSION_HASH}") |
| 115 | + else() |
| 116 | + set(_FULL_VERSION_STRING "v${_VERSION_STRING}") |
| 117 | + endif() |
| 118 | + |
| 119 | + set(${PROJNAME}_VERSION "${_VERSION_STRING}" PARENT_SCOPE) |
| 120 | + set(${PROJNAME}_VERSION_STRING "${_FULL_VERSION_STRING}" PARENT_SCOPE) |
| 121 | +endfunction() |
| 122 | + |
| 123 | +if (CMAKE_SCRIPT_MODE_FILE) |
| 124 | + # This script is being run from the command line. Useful for debugging. |
| 125 | + if (NOT DEFINED GIT_VERSION_FILE) |
| 126 | + message(FATAL_ERROR "Run this script with " |
| 127 | + "cmake -D GIT_VERSION_FILE=git-version.txt -P FlibcppVersion.cmake") |
| 128 | + endif() |
| 129 | + flibcpp_find_version(local ${GIT_VERSION_FILE}) |
| 130 | + message(STATUS "${LOCAL_VERSION}") |
| 131 | + message(STATUS "${LOCAL_VERSION_STRING}") |
| 132 | +endif() |
| 133 | + |
| 134 | +##---------------------------------------------------------------------------## |
| 135 | +## end of flibcpp/cmake/FlibcppVersion.cmake |
| 136 | +##---------------------------------------------------------------------------## |
0 commit comments